Calculadora en visual basic 6.0

Hola tengo un proyecto que hacer:
Tengo que hacer una calculador en Visual Basic 6.0
necesito que el codigo no este tan complejo para que la pueda entender
si alguien tiene algo se lo agradeceria.

Muchas gracias

en un buscador escribi "ayuda" y llege a este foro, si hubiece puesto "haceme un codigo" tambien hubiera llegado no?

El codigo de una calculadora simple esta en miles de paginas, por lo menos dedicale tiempo a una busqueda antes de pedir el codigo hecho.

Una vez me dijeron: Solo pide ayuda como 'ultimo' recurso, lee antes manuales y cualquier tipo de ayuda, ya que abundan hoy en dia.

Saludos

PD: No tomen a mal este post, es que si ni siquiera buscamos nunca aprendemos (hablo por experiencia propia, no por ser un gran programador (en realidad no se nada...) sino porque lo poco que aprendi lo aprend'i gracias a lo que me dijeron aquella vez (leer Una vez me..)

Sabias palabras Fulano...
Estoy de acuerdo

Saludotes....

http://www.somser.com/

en esta pagina esta lo que buscas.

saludos

Lo encontrarás en el directorio Samples del VB 6.0. Debes dominar Arrays.
Cordialmente
Martes, 27-Abril-2004 - [GMT -3 00] 10 23 hs
Te envío el código:
' Copyright (C) 1994 Microsoft Corporation
'
' Tiene el derecho de utilizar, modificar, reproducir y distribuir libremente y sin cargo alguno
' los archivos de las aplicaciones de ejemplo (o sus versiones modificadas) de cualquier forma
' que estime conveniente, asumiendo que acepta que Microsoft no ofrece garantías sobre los
' archivos de las aplicaciones de ejemplo, ni tiene ningún tipo de obligaciones legales con
' respecto a los mismos.
' ------------------------------------------------------------------------
Option Explicit
Dim Op1, Op2 ' Operando introducido previamente.
Dim DecimalFlag As Integer ' ¿Está presente la coma decimal?
Dim NumOps As Integer ' Número de operandos.
Dim LastInput ' Indica el tipo del último evento Keypress.
Dim OpFlag ' Indica la operación pendiente.
Dim TempReadout

' Procedimiento de evento Click para la tecla C (cancelar).
' Restablece la presentación e inicializa las variables.
Private Sub Cancel_Click()
Readout = Format(0, "0.")
Op1 = 0
Op2 = 0
Form_Load
End Sub

' Procedimiento de evento Click para la tecla CE (cancelar entrada).
Private Sub CancelEntry_Click()
Readout = Format(0, "0.")
DecimalFlag = False
LastInput = "CE"
End Sub

' Procedimiento de evento Click para la tecla de la coma decimal (,).
' Si la última tecla presionada fue un operador, inicializa
' la lectura a "0". Si no, agrega la coma decimal
' a la presentación.
Private Sub Decimal_Click()
If LastInput = "NEG" Then
Readout = Format(0, "-0.")
ElseIf LastInput <> "NUMS" Then
Readout = Format(0, "0.")
End If
DecimalFlag = True
LastInput = "NUMS"
End Sub

' Subrutina de inicialización del formulario.
' Establece todas las variables a sus valores iniciales.
Private Sub Form_Load()
DecimalFlag = False
NumOps = 0
LastInput = "NONE"
OpFlag = " "
Readout = Format(0, "0.")
'Decimal.Caption = Format(0, ".")
End Sub

' Procedimiento de evento para las teclas de los números (0-9).
' Agrega el número nuevo a la cantidad mostrada.
Private Sub Number_Click(Index As Integer)
If LastInput <> "NUMS" Then
Readout = Format(0, ".")
DecimalFlag = False
End If
If DecimalFlag Then
Readout = Readout + Number(Index).Caption
Else
Readout = Left(Readout, InStr(Readout, Format(0, ".")) - 1) + Number(Index).Caption + Format(0, ".")
End If
If LastInput = "NEG" Then Readout = "-" & Readout
LastInput = "NUMS"
End Sub

' Procedimiento de evento para las teclas de operación (+, -, x, /, =).
' Si la última tecla presionada formaba parte de un número,
' se incrementa en NumOps. Si ya hubiera presente un operando,
' establece Op1. Si hubiera dos, establece Op1 al resultado
' de la operación sobre Op1 y la cadena de entrada actual,
' y muestra el resultado.
Private Sub Operator_Click(Index As Integer)
TempReadout = Readout
If LastInput = "NUMS" Then
NumOps = NumOps + 1
End If
Select Case NumOps
Case 0
If Operator(Index).Caption = "-" And LastInput <> "NEG" Then
Readout = "-" & Readout
LastInput = "NEG"
End If
Case 1
Op1 = Readout
If Operator(Index).Caption = "-" And LastInput <> "NUMS" And OpFlag <> "=" Then
Readout = "-"
LastInput = "NEG"
End If
Case 2
Op2 = TempReadout
Select Case OpFlag
Case "+"
Op1 = CDbl(Op1) + CDbl(Op2)
Case "-"
Op1 = CDbl(Op1) - CDbl(Op2)
Case "X"
Op1 = CDbl(Op1) * CDbl(Op2)
Case "/"
If Op2 = 0 Then
MsgBox "No se puede dividir entre cero", 48, "Calculadora"
Else
Op1 = CDbl(Op1) / CDbl(Op2)
End If
Case "="
Op1 = CDbl(Op2)
Case "%"
Op1 = CDbl(Op1) * CDbl(Op2)
End Select
Readout = Op1
NumOps = 1
End Select
If LastInput <> "NEG" Then
LastInput = "OPS"
OpFlag = Operator(Index).Caption
End If
End Sub

' Procedimiento de evento Click para la tecla de porcentaje (%).
' Calcula y muestra el porcentaje del primer operando.
Private Sub Percent_Click()
Readout = Readout / 100
LastInput = "Ops"
OpFlag = "%"
NumOps = NumOps + 1
DecimalFlag = True
End Sub

Este chavo pregunta que en que escuela vas, si te interesa informacion, porfavor manda un mail, el creo que la hizo hasta cientifica

Echale un vistazo a esta calculadora, el cádigo no es excesivamente complejo (la hice a partir de un libro de iniciación en la programación).